cmake_minimum_required(VERSION 3.28)
project(FluidSimCpp VERSION 0.1.0 LANGUAGES CXX)

option(FLUIDSIM_BUILD_DESKTOP "Build the SFML windowed simulator with keyboard controls and audio" ON)
set(FLUIDSIM_FONT_FILE "" CACHE FILEPATH "Optional font file copied beside the desktop executable")

add_library(fluidsim_core
    src/ecu.cpp
    src/turbocharger.cpp
    src/engine.cpp
    src/crankcase.cpp
    src/two_stroke_cylinder.cpp
    src/two_stroke_scenario.cpp
    src/helmholtz_scenario.cpp
    src/pulse_test_scenario.cpp
    src/audio_processing.cpp
    src/outdoor_audio.cpp
    src/outdoor_exhaust_reverb.cpp
    src/mechanical_sound_processor.cpp
    src/scenario.cpp
    src/solver.cpp
    src/vehicle.cpp
    src/simulation_ring_buffer.cpp
)
target_include_directories(fluidsim_core PUBLIC include)
target_compile_features(fluidsim_core PUBLIC cxx_std_20)
option(FLUIDSIM_ENABLE_SIMD "Allow compiler SIMD in fluid kernels without fast-math" ON)
if(CMAKE_CXX_COMPILER_ID MATCHES "GNU|Clang")
    if(FLUIDSIM_ENABLE_SIMD)
        target_compile_options(fluidsim_core PUBLIC -fno-math-errno)
    elseif(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
        target_compile_options(fluidsim_core PUBLIC -fno-tree-vectorize)
    else()
        target_compile_options(fluidsim_core PUBLIC -fno-vectorize -fno-slp-vectorize)
    endif()
elseif(MSVC AND NOT FLUIDSIM_ENABLE_SIMD)
    target_compile_options(fluidsim_core PUBLIC /Qvec-)
endif()

add_executable(fluidsim_cpp src/main.cpp)
target_link_libraries(fluidsim_cpp PRIVATE fluidsim_core)

add_executable(fluidsim_parity_trace tools/parity_trace.cpp)
target_link_libraries(fluidsim_parity_trace PRIVATE fluidsim_core)

if(FLUIDSIM_BUILD_DESKTOP)
    find_package(SFML 3.0.2 COMPONENTS Graphics Audio QUIET)
    if(NOT SFML_FOUND)
        include(FetchContent)
        set(SFML_BUILD_AUDIO ON CACHE BOOL "" FORCE)
        set(SFML_BUILD_GRAPHICS ON CACHE BOOL "" FORCE)
        set(SFML_BUILD_WINDOW ON CACHE BOOL "" FORCE)
        set(SFML_BUILD_NETWORK OFF CACHE BOOL "" FORCE)
        set(SFML_BUILD_EXAMPLES OFF CACHE BOOL "" FORCE)
        set(SFML_BUILD_TEST_SUITE OFF CACHE BOOL "" FORCE)
        set(BUILD_SHARED_LIBS OFF CACHE BOOL "" FORCE)
        FetchContent_Declare(SFML
            GIT_REPOSITORY https://github.com/SFML/SFML.git
            GIT_TAG 3.0.2
            GIT_SHALLOW TRUE
            EXCLUDE_FROM_ALL
            SYSTEM
        )
        FetchContent_MakeAvailable(SFML)
    endif()
    add_executable(fluidsim_desktop src/desktop_main.cpp src/audio_output_stream.cpp src/sound_engine.cpp)
    target_link_libraries(fluidsim_desktop PRIVATE fluidsim_core SFML::Graphics SFML::Audio)
    if(MSVC)
        target_compile_options(fluidsim_desktop PRIVATE /W4 /permissive-)
    else()
        target_compile_options(fluidsim_desktop PRIVATE -Wall -Wextra -Wpedantic)
    endif()
    if(FLUIDSIM_FONT_FILE)
        if(NOT EXISTS "${FLUIDSIM_FONT_FILE}")
            message(FATAL_ERROR "FLUIDSIM_FONT_FILE does not exist: ${FLUIDSIM_FONT_FILE}")
        endif()
        add_custom_command(TARGET fluidsim_desktop POST_BUILD
            COMMAND ${CMAKE_COMMAND} -E make_directory "$<TARGET_FILE_DIR:fluidsim_desktop>/fonts"
            COMMAND ${CMAKE_COMMAND} -E copy_if_different "${FLUIDSIM_FONT_FILE}"
                    "$<TARGET_FILE_DIR:fluidsim_desktop>/fonts/FiraCodeNerdFont-Medium.ttf")
    elseif(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/../fonts/FiraCodeNerdFont-Medium.ttf")
        add_custom_command(TARGET fluidsim_desktop POST_BUILD
            COMMAND ${CMAKE_COMMAND} -E make_directory "$<TARGET_FILE_DIR:fluidsim_desktop>/fonts"
            COMMAND ${CMAKE_COMMAND} -E copy_if_different
                    "${CMAKE_CURRENT_SOURCE_DIR}/../fonts/FiraCodeNerdFont-Medium.ttf"
                    "$<TARGET_FILE_DIR:fluidsim_desktop>/fonts/FiraCodeNerdFont-Medium.ttf")
    else()
        message(STATUS "No bundled font; desktop will try installed system fonts. Set FLUIDSIM_FONT_FILE to bundle one.")
    endif()
endif()

if(MSVC)
    target_compile_options(fluidsim_core PRIVATE /W4 /permissive-)
    target_compile_options(fluidsim_cpp PRIVATE /W4 /permissive-)
    target_compile_options(fluidsim_parity_trace PRIVATE /W4 /permissive-)
else()
    target_compile_options(fluidsim_core PRIVATE -Wall -Wextra -Wpedantic)
    target_compile_options(fluidsim_cpp PRIVATE -Wall -Wextra -Wpedantic)
    target_compile_options(fluidsim_parity_trace PRIVATE -Wall -Wextra -Wpedantic)
endif()

include(CTest)
if(BUILD_TESTING)
    add_executable(fluidsim_saab_turbo_regression tests/saab_turbo_regression.cpp)
    target_link_libraries(fluidsim_saab_turbo_regression PRIVATE fluidsim_core)
    add_test(NAME fluidsim_saab_turbo_regression COMMAND fluidsim_saab_turbo_regression)
endif()
if(BUILD_TESTING)
    add_executable(fluidsim_physics_tests tests/physics_tests.cpp)
    target_link_libraries(fluidsim_physics_tests PRIVATE fluidsim_core)
    add_test(NAME fluidsim_physics_tests COMMAND fluidsim_physics_tests)
endif()

add_executable(fluidsim_physics_benchmark tools/physics_benchmark.cpp)
target_link_libraries(fluidsim_physics_benchmark PRIVATE fluidsim_core)
add_executable(fluidsim_scenario_benchmark tools/scenario_benchmark.cpp)
target_link_libraries(fluidsim_scenario_benchmark PRIVATE fluidsim_core)
if(BUILD_TESTING)
    add_executable(fluidsim_fluid_validation tests/fluid_validation.cpp)
    target_link_libraries(fluidsim_fluid_validation PRIVATE fluidsim_core)
    add_test(NAME fluidsim_fluid_validation COMMAND fluidsim_fluid_validation)
endif()
find_package(Threads REQUIRED)
target_link_libraries(fluidsim_core PUBLIC Threads::Threads)
add_executable(fluidsim_thread_benchmark tools/thread_benchmark.cpp)
target_link_libraries(fluidsim_thread_benchmark PRIVATE fluidsim_core)
if(BUILD_TESTING)
    add_executable(fluidsim_intake_regression tests/intake_regression.cpp)
    target_link_libraries(fluidsim_intake_regression PRIVATE fluidsim_core)
    add_test(NAME fluidsim_intake_regression COMMAND fluidsim_intake_regression)
endif()

add_executable(fluidsim_audio_capture tools/audio_capture.cpp)
target_link_libraries(fluidsim_audio_capture PRIVATE fluidsim_core)
add_executable(fluidsim_two_stroke_benchmark tools/two_stroke_benchmark.cpp)
target_link_libraries(fluidsim_two_stroke_benchmark PRIVATE fluidsim_core)
add_executable(fluidsim_turbo_benchmark tools/turbo_benchmark.cpp)
target_link_libraries(fluidsim_turbo_benchmark PRIVATE fluidsim_core)
if(BUILD_TESTING)
    add_executable(fluidsim_outdoor_audio_tests tests/outdoor_audio_tests.cpp)
    target_link_libraries(fluidsim_outdoor_audio_tests PRIVATE fluidsim_core)
    add_test(NAME fluidsim_outdoor_audio_tests COMMAND fluidsim_outdoor_audio_tests)
    add_executable(fluidsim_two_stroke_regression tests/two_stroke_regression.cpp)
    target_link_libraries(fluidsim_two_stroke_regression PRIVATE fluidsim_core)
    add_test(NAME fluidsim_two_stroke_regression COMMAND fluidsim_two_stroke_regression)
    add_executable(fluidsim_two_stroke_physics tests/two_stroke_physics.cpp)
    target_link_libraries(fluidsim_two_stroke_physics PRIVATE fluidsim_core)
    add_test(NAME fluidsim_two_stroke_physics COMMAND fluidsim_two_stroke_physics)
    add_executable(fluidsim_b205_regression tests/b205_regression.cpp)
    target_link_libraries(fluidsim_b205_regression PRIVATE fluidsim_core)
    add_test(NAME fluidsim_b205_regression COMMAND fluidsim_b205_regression)
    add_executable(fluidsim_turbo_physics tests/turbo_physics.cpp)
    target_link_libraries(fluidsim_turbo_physics PRIVATE fluidsim_core)
    add_test(NAME fluidsim_turbo_physics COMMAND fluidsim_turbo_physics)
    add_executable(fluidsim_turbo_twin_regression tests/turbo_twin_regression.cpp)
    target_link_libraries(fluidsim_turbo_twin_regression PRIVATE fluidsim_core)
    add_test(NAME fluidsim_turbo_twin_regression COMMAND fluidsim_turbo_twin_regression)
endif()
