cmake_minimum_required(VERSION 3.28)
project(FluidSimCpp VERSION 0.1.0 LANGUAGES CXX)

option(FLUIDSIM_BUILD_DESKTOP "Build the SFML windowed simulator with keyboard controls and audio" ON)
set(FLUIDSIM_FONT_FILE "" CACHE FILEPATH "Optional font file copied beside the desktop executable")

add_library(fluidsim_core
    src/engine_config.cpp
    src/carburetor.cpp
    src/ecu.cpp
    src/fuel_injector.cpp
    src/engine.cpp
    src/crankcase.cpp
    src/two_stroke_cylinder.cpp
    src/two_stroke_scenario.cpp
    src/helmholtz_scenario.cpp
    src/pulse_test_scenario.cpp
    src/audio_processing.cpp
    src/outdoor_audio.cpp
    src/outdoor_exhaust_reverb.cpp
    src/scenario.cpp
    src/scenario_snapshot.cpp
    src/scenario_geometry.cpp
    src/physical_geometry.cpp
    src/machine.cpp
    src/machine_ports.cpp
    src/mechanics.cpp
    src/machine_mechanics.cpp
    src/machine_sensors.cpp
    src/machine_logic.cpp
    src/logic_runtime.cpp
    src/logic_serialization.cpp
    src/logic_assembly.cpp
    src/logic_example.cpp
    src/speed_density_example.cpp
    src/machine_simulation.cpp
    src/machine_import.cpp
    src/solver.cpp
    src/vehicle.cpp
    src/simulation_ring_buffer.cpp
)
target_include_directories(fluidsim_core PUBLIC include)
target_include_directories(fluidsim_core SYSTEM PRIVATE third_party/tomlplusplus)
target_compile_definitions(fluidsim_core PRIVATE FLUIDSIM_ENGINE_SOURCE_DIR="${CMAKE_CURRENT_SOURCE_DIR}/engines")
target_compile_features(fluidsim_core PUBLIC cxx_std_20)
option(FLUIDSIM_ENABLE_SIMD "Allow compiler SIMD in fluid kernels without fast-math" ON)
if(CMAKE_CXX_COMPILER_ID MATCHES "GNU|Clang")
    if(FLUIDSIM_ENABLE_SIMD)
        target_compile_options(fluidsim_core PUBLIC -fno-math-errno)
    elseif(CMAKE_CXX_COMPILER_ID STREQUAL "GNU")
        target_compile_options(fluidsim_core PUBLIC -fno-tree-vectorize)
    else()
        target_compile_options(fluidsim_core PUBLIC -fno-vectorize -fno-slp-vectorize)
    endif()
elseif(MSVC AND NOT FLUIDSIM_ENABLE_SIMD)
    target_compile_options(fluidsim_core PUBLIC /Qvec-)
endif()

add_executable(fluidsim_cpp src/main.cpp)
target_link_libraries(fluidsim_cpp PRIVATE fluidsim_core)

add_executable(fluidsim_parity_trace tools/parity_trace.cpp)
target_link_libraries(fluidsim_parity_trace PRIVATE fluidsim_core)
add_executable(fluidsim_migrate_geometry tools/migrate_geometry.cpp)
target_link_libraries(fluidsim_migrate_geometry PRIVATE fluidsim_core)
add_executable(fluidsim_machine_benchmark tools/machine_benchmark.cpp)
target_link_libraries(fluidsim_machine_benchmark PRIVATE fluidsim_core)

if(FLUIDSIM_BUILD_DESKTOP)
    find_package(SFML 3.0.2 COMPONENTS Graphics Audio QUIET)
    if(NOT SFML_FOUND)
        include(FetchContent)
        set(SFML_BUILD_AUDIO ON CACHE BOOL "" FORCE)
        set(SFML_BUILD_GRAPHICS ON CACHE BOOL "" FORCE)
        set(SFML_BUILD_WINDOW ON CACHE BOOL "" FORCE)
        set(SFML_BUILD_NETWORK OFF CACHE BOOL "" FORCE)
        set(SFML_BUILD_EXAMPLES OFF CACHE BOOL "" FORCE)
        set(SFML_BUILD_TEST_SUITE OFF CACHE BOOL "" FORCE)
        set(BUILD_SHARED_LIBS OFF CACHE BOOL "" FORCE)
        FetchContent_Declare(SFML
            GIT_REPOSITORY https://github.com/SFML/SFML.git
            GIT_TAG 3.0.2
            GIT_SHALLOW TRUE
            EXCLUDE_FROM_ALL
            SYSTEM
        )
        FetchContent_MakeAvailable(SFML)
    endif()
    find_package(OpenGL REQUIRED)
    add_library(fluidsim_desktop_rendering
        src/desktop_ui.cpp src/scenario_menu.cpp src/engine_schematic.cpp src/engine_renderer_3d.cpp src/dyno_renderer.cpp
        src/machine_builder.cpp src/builder_geometry.cpp src/machine_renderer_3d.cpp src/window_presentation.cpp src/logic_editor.cpp
        src/audio_output_stream.cpp src/sound_engine.cpp)
    target_link_libraries(fluidsim_desktop_rendering PUBLIC fluidsim_core SFML::Graphics SFML::Audio OpenGL::GL)
    if(WIN32)
        target_link_libraries(fluidsim_desktop_rendering PRIVATE user32)
    endif()
    if(MSVC)
        target_compile_options(fluidsim_desktop_rendering PRIVATE /W4 /permissive-)
    else()
        target_compile_options(fluidsim_desktop_rendering PRIVATE -Wall -Wextra -Wpedantic)
    endif()
    add_executable(fluidsim_desktop src/desktop_main.cpp)
    target_link_libraries(fluidsim_desktop PRIVATE fluidsim_desktop_rendering SFML::Audio)
    add_executable(fluidsim_machine_render_benchmark tools/machine_render_benchmark.cpp)
    target_link_libraries(fluidsim_machine_render_benchmark PRIVATE fluidsim_desktop_rendering)
    if(MSVC)
        target_compile_options(fluidsim_desktop PRIVATE /W4 /permissive-)
    else()
        target_compile_options(fluidsim_desktop PRIVATE -Wall -Wextra -Wpedantic)
    endif()
    if(FLUIDSIM_FONT_FILE)
        if(NOT EXISTS "${FLUIDSIM_FONT_FILE}")
            message(FATAL_ERROR "FLUIDSIM_FONT_FILE does not exist: ${FLUIDSIM_FONT_FILE}")
        endif()
        add_custom_command(TARGET fluidsim_desktop POST_BUILD
            COMMAND ${CMAKE_COMMAND} -E make_directory "$<TARGET_FILE_DIR:fluidsim_desktop>/fonts"
            COMMAND ${CMAKE_COMMAND} -E copy_if_different "${FLUIDSIM_FONT_FILE}"
                    "$<TARGET_FILE_DIR:fluidsim_desktop>/fonts/FiraCodeNerdFont-Medium.ttf")
    elseif(EXISTS "${CMAKE_CURRENT_SOURCE_DIR}/../fonts/FiraCodeNerdFont-Medium.ttf")
        add_custom_command(TARGET fluidsim_desktop POST_BUILD
            COMMAND ${CMAKE_COMMAND} -E make_directory "$<TARGET_FILE_DIR:fluidsim_desktop>/fonts"
            COMMAND ${CMAKE_COMMAND} -E copy_if_different
                    "${CMAKE_CURRENT_SOURCE_DIR}/../fonts/FiraCodeNerdFont-Medium.ttf"
                    "$<TARGET_FILE_DIR:fluidsim_desktop>/fonts/FiraCodeNerdFont-Medium.ttf")
    else()
        message(STATUS "No bundled font; desktop will try installed system fonts. Set FLUIDSIM_FONT_FILE to bundle one.")
    endif()
endif()

if(MSVC)
    target_compile_options(fluidsim_core PRIVATE /W4 /permissive-)
    target_compile_options(fluidsim_cpp PRIVATE /W4 /permissive-)
    target_compile_options(fluidsim_parity_trace PRIVATE /W4 /permissive-)
else()
    target_compile_options(fluidsim_core PRIVATE -Wall -Wextra -Wpedantic)
    target_compile_options(fluidsim_cpp PRIVATE -Wall -Wextra -Wpedantic)
    target_compile_options(fluidsim_parity_trace PRIVATE -Wall -Wextra -Wpedantic)
endif()

include(CTest)
if(BUILD_TESTING)
    add_executable(fluidsim_speed_density_tests tests/speed_density_tests.cpp)
    target_link_libraries(fluidsim_speed_density_tests PRIVATE fluidsim_core)
    add_test(NAME fluidsim_speed_density_tests COMMAND fluidsim_speed_density_tests)
    add_executable(fluidsim_sensor_ecu_tests tests/sensor_ecu_tests.cpp)
    target_link_libraries(fluidsim_sensor_ecu_tests PRIVATE fluidsim_core)
    add_test(NAME fluidsim_sensor_ecu_tests COMMAND fluidsim_sensor_ecu_tests)
    add_executable(fluidsim_logic_tests tests/logic_tests.cpp)
    target_link_libraries(fluidsim_logic_tests PRIVATE fluidsim_core)
    add_test(NAME fluidsim_logic_tests COMMAND fluidsim_logic_tests)
    add_executable(fluidsim_machine_logic_tests tests/machine_logic_tests.cpp)
    target_link_libraries(fluidsim_machine_logic_tests PRIVATE fluidsim_core)
    add_test(NAME fluidsim_machine_logic_tests COMMAND fluidsim_machine_logic_tests)
    add_executable(fluidsim_machine_tests tests/machine_tests.cpp)
    target_link_libraries(fluidsim_machine_tests PRIVATE fluidsim_core)
    add_test(NAME fluidsim_machine_tests COMMAND fluidsim_machine_tests)
    add_executable(fluidsim_machine_sensor_tests tests/machine_sensor_tests.cpp)
    target_link_libraries(fluidsim_machine_sensor_tests PRIVATE fluidsim_core)
    target_compile_definitions(fluidsim_machine_sensor_tests PRIVATE FLUIDSIM_SENSOR_EXAMPLE_FILE="${CMAKE_CURRENT_SOURCE_DIR}/machines/sensor-bench.machine.toml")
    add_test(NAME fluidsim_machine_sensor_tests COMMAND fluidsim_machine_sensor_tests)
    add_executable(fluidsim_machine_port_tests tests/machine_port_tests.cpp)
    target_link_libraries(fluidsim_machine_port_tests PRIVATE fluidsim_core)
    add_test(NAME fluidsim_machine_port_tests COMMAND fluidsim_machine_port_tests)
    add_executable(fluidsim_mechanics_tests tests/mechanics_tests.cpp)
    target_link_libraries(fluidsim_mechanics_tests PRIVATE fluidsim_core)
    add_test(NAME fluidsim_mechanics_tests COMMAND fluidsim_mechanics_tests)
    add_executable(fluidsim_machine_mechanics_tests tests/machine_mechanics_tests.cpp)
    target_link_libraries(fluidsim_machine_mechanics_tests PRIVATE fluidsim_core)
    add_test(NAME fluidsim_machine_mechanics_tests COMMAND fluidsim_machine_mechanics_tests)
    add_executable(fluidsim_physical_geometry_tests tests/physical_geometry_tests.cpp)
    target_link_libraries(fluidsim_physical_geometry_tests PRIVATE fluidsim_core)
    target_include_directories(fluidsim_physical_geometry_tests SYSTEM PRIVATE third_party/tomlplusplus)
    add_test(NAME fluidsim_physical_geometry_tests COMMAND fluidsim_physical_geometry_tests)
    add_executable(fluidsim_mesh_resolution_tests tests/mesh_resolution_tests.cpp)
    target_link_libraries(fluidsim_mesh_resolution_tests PRIVATE fluidsim_core)
    add_test(NAME fluidsim_mesh_resolution_tests COMMAND fluidsim_mesh_resolution_tests)
    add_executable(fluidsim_junction_tests tests/junction_tests.cpp)
    target_link_libraries(fluidsim_junction_tests PRIVATE fluidsim_core)
    add_test(NAME fluidsim_junction_tests COMMAND fluidsim_junction_tests)
    add_executable(fluidsim_live_tuning_tests tests/live_tuning_tests.cpp)
    target_link_libraries(fluidsim_live_tuning_tests PRIVATE fluidsim_core)
    add_test(NAME fluidsim_live_tuning_tests COMMAND fluidsim_live_tuning_tests)
    add_executable(fluidsim_engine_config_tests tests/engine_config_tests.cpp)
    target_link_libraries(fluidsim_engine_config_tests PRIVATE fluidsim_core)
    add_test(NAME fluidsim_engine_config_tests COMMAND fluidsim_engine_config_tests)
    add_executable(fluidsim_scenario_examples tests/scenario_examples.cpp)
    target_link_libraries(fluidsim_scenario_examples PRIVATE fluidsim_core)
    add_test(NAME fluidsim_scenario_examples COMMAND fluidsim_scenario_examples)
endif()
if(BUILD_TESTING AND FLUIDSIM_BUILD_DESKTOP)
    add_executable(fluidsim_logic_editor_tests tests/logic_editor_tests.cpp)
    target_link_libraries(fluidsim_logic_editor_tests PRIVATE fluidsim_desktop_rendering)
    add_test(NAME fluidsim_logic_editor_tests COMMAND fluidsim_logic_editor_tests)
    add_executable(fluidsim_menu_tests tests/menu_tests.cpp)
    target_link_libraries(fluidsim_menu_tests PRIVATE fluidsim_desktop_rendering)
    add_test(NAME fluidsim_menu_tests COMMAND fluidsim_menu_tests)
    add_test(NAME fluidsim_window_tests COMMAND fluidsim_menu_tests --window-check)
    add_executable(fluidsim_machine_builder_tests tests/machine_builder_tests.cpp)
    target_link_libraries(fluidsim_machine_builder_tests PRIVATE fluidsim_desktop_rendering)
    add_test(NAME fluidsim_machine_builder_tests COMMAND fluidsim_machine_builder_tests)
    add_executable(fluidsim_desktop_ui_tests tests/desktop_ui_tests.cpp)
    target_link_libraries(fluidsim_desktop_ui_tests PRIVATE fluidsim_desktop_rendering)
    add_test(NAME fluidsim_desktop_ui_tests COMMAND fluidsim_desktop_ui_tests)
endif()
if(BUILD_TESTING)
    add_executable(fluidsim_physics_tests tests/physics_tests.cpp)
    target_link_libraries(fluidsim_physics_tests PRIVATE fluidsim_core)
    add_test(NAME fluidsim_physics_tests COMMAND fluidsim_physics_tests)
endif()

add_executable(fluidsim_physics_benchmark tools/physics_benchmark.cpp)
target_link_libraries(fluidsim_physics_benchmark PRIVATE fluidsim_core)
add_executable(fluidsim_scenario_benchmark tools/scenario_benchmark.cpp)
target_link_libraries(fluidsim_scenario_benchmark PRIVATE fluidsim_core)
add_executable(fluidsim_scenario_profile tools/scenario_profile.cpp)
target_link_libraries(fluidsim_scenario_profile PRIVATE fluidsim_core)
if(BUILD_TESTING)
    add_test(NAME fluidsim_v8_exhaust_regression COMMAND fluidsim_scenario_benchmark 8 coast v8)
endif()
if(BUILD_TESTING)
    add_executable(fluidsim_fluid_validation tests/fluid_validation.cpp)
    target_link_libraries(fluidsim_fluid_validation PRIVATE fluidsim_core)
    add_test(NAME fluidsim_fluid_validation COMMAND fluidsim_fluid_validation)
    add_test(NAME fluidsim_fluid_validation_hlle COMMAND fluidsim_fluid_validation hlle)
    add_test(NAME fluidsim_fluid_validation_hllc COMMAND fluidsim_fluid_validation hllc)
    add_test(NAME fluidsim_fluid_validation_muscl COMMAND fluidsim_fluid_validation muscl)
endif()
find_package(Threads REQUIRED)
target_link_libraries(fluidsim_core PUBLIC Threads::Threads)
add_executable(fluidsim_thread_benchmark tools/thread_benchmark.cpp)
target_link_libraries(fluidsim_thread_benchmark PRIVATE fluidsim_core)
if(BUILD_TESTING)
    add_executable(fluidsim_intake_regression tests/intake_regression.cpp)
    target_link_libraries(fluidsim_intake_regression PRIVATE fluidsim_core)
    add_test(NAME fluidsim_intake_regression COMMAND fluidsim_intake_regression)
endif()

add_executable(fluidsim_acoustic_benchmark tools/acoustic_benchmark.cpp)
target_link_libraries(fluidsim_acoustic_benchmark PRIVATE fluidsim_core)
if(BUILD_TESTING)
    add_test(NAME fluidsim_acoustic_benchmark COMMAND fluidsim_acoustic_benchmark "${CMAKE_CURRENT_BINARY_DIR}/acoustic-validation")
endif()
add_executable(fluidsim_audio_capture tools/audio_capture.cpp)
target_link_libraries(fluidsim_audio_capture PRIVATE fluidsim_core)
add_executable(fluidsim_two_stroke_benchmark tools/two_stroke_benchmark.cpp)
target_link_libraries(fluidsim_two_stroke_benchmark PRIVATE fluidsim_core)
if(BUILD_TESTING)
    add_executable(fluidsim_outdoor_audio_tests tests/outdoor_audio_tests.cpp)
    target_link_libraries(fluidsim_outdoor_audio_tests PRIVATE fluidsim_core)
    add_test(NAME fluidsim_outdoor_audio_tests COMMAND fluidsim_outdoor_audio_tests)
    add_executable(fluidsim_two_stroke_regression tests/two_stroke_regression.cpp)
    target_link_libraries(fluidsim_two_stroke_regression PRIVATE fluidsim_core)
    add_test(NAME fluidsim_two_stroke_regression COMMAND fluidsim_two_stroke_regression)
    add_executable(fluidsim_two_stroke_physics tests/two_stroke_physics.cpp)
    target_link_libraries(fluidsim_two_stroke_physics PRIVATE fluidsim_core)
    add_test(NAME fluidsim_two_stroke_physics COMMAND fluidsim_two_stroke_physics)
    add_executable(fluidsim_b205_regression tests/b205_regression.cpp)
    target_link_libraries(fluidsim_b205_regression PRIVATE fluidsim_core)
    add_test(NAME fluidsim_b205_regression COMMAND fluidsim_b205_regression)
endif()

add_executable(fluidsim_carb_calibration tools/carb_calibration.cpp)
target_link_libraries(fluidsim_carb_calibration PRIVATE fluidsim_core)
if(BUILD_TESTING)
    add_test(NAME fluidsim_carb_calibration COMMAND fluidsim_carb_calibration --check)
endif()

include(cmake/MinGWRuntime.cmake)

# Keep definitions beside every built executable, including tests and CLI tools.
add_custom_target(fluidsim_engine_assets ALL
    COMMAND ${CMAKE_COMMAND}
        "-DSOURCE=${CMAKE_CURRENT_SOURCE_DIR}/engines"
        "-DDESTINATION=${CMAKE_CURRENT_BINARY_DIR}/engines"
        -P "${CMAKE_CURRENT_SOURCE_DIR}/cmake/CopyEngineConfigs.cmake")
get_property(fluidsim_targets DIRECTORY PROPERTY BUILDSYSTEM_TARGETS)
foreach(target IN LISTS fluidsim_targets)
    get_target_property(target_type ${target} TYPE)
    if(target_type STREQUAL "EXECUTABLE")
        add_dependencies(${target} fluidsim_engine_assets)
    endif()
endforeach()
