Port FluidSim core and scenarios to C++20

CMakeLists.txt

@@ -0,0 +1,75 @@
+cmake_minimum_required(VERSION 3.28)
+project(FluidSimCpp VERSION 0.1.0 LANGUAGES CXX)
+
+option(FLUIDSIM_BUILD_DESKTOP "Build the SFML windowed simulator with keyboard controls and audio" ON)
+
+add_library(fluidsim_core
+    src/engine.cpp
+    src/crankcase.cpp
+    src/two_stroke_cylinder.cpp
+    src/two_stroke_scenario.cpp
+    src/helmholtz_scenario.cpp
+    src/pulse_test_scenario.cpp
+    src/audio_processing.cpp
+    src/outdoor_exhaust_reverb.cpp
+    src/mechanical_sound_processor.cpp
+    src/scenario.cpp
+    src/solver.cpp
+    src/vehicle.cpp
+    src/simulation_ring_buffer.cpp
+)
+target_include_directories(fluidsim_core PUBLIC include)
+target_compile_features(fluidsim_core PUBLIC cxx_std_20)
+
+add_executable(fluidsim_cpp src/main.cpp)
+target_link_libraries(fluidsim_cpp PRIVATE fluidsim_core)
+
+add_executable(fluidsim_parity_trace tools/parity_trace.cpp)
+target_link_libraries(fluidsim_parity_trace PRIVATE fluidsim_core)
+
+if(FLUIDSIM_BUILD_DESKTOP)
+    find_package(SFML 3.0.2 COMPONENTS Graphics Audio QUIET)
+    if(NOT SFML_FOUND)
+        include(FetchContent)
+        set(SFML_BUILD_AUDIO ON CACHE BOOL "" FORCE)
+        set(SFML_BUILD_GRAPHICS ON CACHE BOOL "" FORCE)
+        set(SFML_BUILD_WINDOW ON CACHE BOOL "" FORCE)
+        set(SFML_BUILD_NETWORK OFF CACHE BOOL "" FORCE)
+        set(SFML_BUILD_EXAMPLES OFF CACHE BOOL "" FORCE)
+        set(SFML_BUILD_TEST_SUITE OFF CACHE BOOL "" FORCE)
+        set(BUILD_SHARED_LIBS OFF CACHE BOOL "" FORCE)
+        FetchContent_Declare(SFML
+            GIT_REPOSITORY https://github.com/SFML/SFML.git
+            GIT_TAG 3.0.2
+            GIT_SHALLOW TRUE
+            EXCLUDE_FROM_ALL
+            SYSTEM
+        )
+        FetchContent_MakeAvailable(SFML)
+    endif()
+    add_executable(fluidsim_desktop src/desktop_main.cpp src/audio_output_stream.cpp src/sound_engine.cpp)
+    target_link_libraries(fluidsim_desktop PRIVATE fluidsim_core SFML::Graphics SFML::Audio)
+    if(MSVC)
+        target_compile_options(fluidsim_desktop PRIVATE /W4 /permissive-)
+    else()
+        target_compile_options(fluidsim_desktop PRIVATE -Wall -Wextra -Wpedantic)
+    endif()
+    file(COPY "${CMAKE_CURRENT_SOURCE_DIR}/../fonts" DESTINATION "${CMAKE_CURRENT_BINARY_DIR}")
+endif()
+
+if(MSVC)
+    target_compile_options(fluidsim_core PRIVATE /W4 /permissive-)
+    target_compile_options(fluidsim_cpp PRIVATE /W4 /permissive-)
+    target_compile_options(fluidsim_parity_trace PRIVATE /W4 /permissive-)
+else()
+    target_compile_options(fluidsim_core PRIVATE -Wall -Wextra -Wpedantic)
+    target_compile_options(fluidsim_cpp PRIVATE -Wall -Wextra -Wpedantic)
+    target_compile_options(fluidsim_parity_trace PRIVATE -Wall -Wextra -Wpedantic)
+endif()
+
+include(CTest)
+if(BUILD_TESTING)
+    add_executable(fluidsim_physics_tests tests/physics_tests.cpp)
+    target_link_libraries(fluidsim_physics_tests PRIVATE fluidsim_core)
+    add_test(NAME fluidsim_physics_tests COMMAND fluidsim_physics_tests)
+endif()